C (c) CROWN COPYRIGHT 1995, METEOROLOGICAL OFFICE, All Rights Reserved.            RAD_ALL.24494 
C                                                                                  RAD_ALL.24495 
C Use, duplication or disclosure of this code is subject to the                    RAD_ALL.24496 
C restrictions as set forth in the contract.                                       RAD_ALL.24497 
C                                                                                  RAD_ALL.24498 
C                Meteorological Office                                             RAD_ALL.24499 
C                London Road                                                       RAD_ALL.24500 
C                BRACKNELL                                                         RAD_ALL.24501 
C                Berkshire UK                                                      RAD_ALL.24502 
C                RG12 2SZ                                                          RAD_ALL.24503 
C                                                                                  RAD_ALL.24504 
C If no contract has been raised with this copy of the code, the use,              RAD_ALL.24505 
C duplication or disclosure of it is strictly prohibited.  Permission              RAD_ALL.24506 
C to do so must first be obtained in writing from the Head of Numerical            RAD_ALL.24507 
C Modelling at the above address.                                                  RAD_ALL.24508 
C ******************************COPYRIGHT******************************            RAD_ALL.24509 
C                                                                                  RAD_ALL.24510 
!+ Subroutine to calculate basic coefficients in two-stream equations.             RAD_ALL.24511 
!                                                                                  RAD_ALL.24512 
! Method:                                                                          RAD_ALL.24513 
!       Depending on the two-stream equations employed, the                        RAD_ALL.24514 
!       appropriate coefficients for the fluxes are calculated.                    RAD_ALL.24515 
!                                                                                  RAD_ALL.24516 
! Current Owner of Code: J. M. Edwards                                             RAD_ALL.24517 
!                                                                                  RAD_ALL.24518 
! History:                                                                         RAD_ALL.24519 
!       Version         Date                    Comment                            RAD_ALL.24520 
!       4.0             27-07-95                Original Code                      RAD_ALL.24521 
!                                               (J. M. Edwards)                    RAD_ALL.24522 
!       4.2             08-08-96                PIFM85 restored to                 RAD_ALL.24523 
!                                               original form. PIFM80              RAD_ALL.24524 
!                                               introduced.                        RAD_ALL.24525 
!                                               (J. M. Edwards)                    RAD_ALL.24526 
!                                                                                  RAD_ALL.24527 
! Description of Code:                                                             RAD_ALL.24528 
!   FORTRAN 77  with extensions listed in documentation.                           RAD_ALL.24529 
!                                                                                  RAD_ALL.24530 
!- ---------------------------------------------------------------------           RAD_ALL.24531 
      SUBROUTINE TWO_COEFF_BASIC(IERR                                              RAD_ALL.24532 
     &   , N_PROFILE, I_LAYER_FIRST, I_LAYER_LAST                                  RAD_ALL.24533 
     &   , I_2STREAM                                                               RAD_ALL.24534 
     &   , ASYMMETRY, OMEGA                                                        RAD_ALL.24535 
     &   , SUM, DIFF                                                               RAD_ALL.24536 
     &   , NPD_PROFILE, NPD_LAYER                                                  RAD_ALL.24537 
     &   )                                                                         RAD_ALL.24538 
!                                                                                  RAD_ALL.24539 
!                                                                                  RAD_ALL.24540 
!                                                                                  RAD_ALL.24541 
      IMPLICIT NONE                                                                RAD_ALL.24542 
!                                                                                  RAD_ALL.24543 
!                                                                                  RAD_ALL.24544 
!     SIZES OF DUMMY ARRAYS.                                                       RAD_ALL.24545 
      INTEGER   !, INTENT(IN)                                                      RAD_ALL.24546 
     &     NPD_PROFILE                                                             RAD_ALL.24547 
!             MAXIMUM NUMBER OF PROFILES                                           RAD_ALL.24548 
     &   , NPD_LAYER                                                               RAD_ALL.24549 
!             MAXIMUM NUMBER OF LAYERS                                             RAD_ALL.24550 
!                                                                                  RAD_ALL.24551 
!     INCLUDE COMDECKS.                                                            RAD_ALL.24552 
!     ------------------------------------------------------------------           STDIO3A.2     
!     COMDECK FOR TWO-STREAM RADIATION CODE.                                       STDIO3A.3     
!                                                                                  STDIO3A.4     
!     MODULE TO SET UNIT NUMBERS FOR STANDARD I/O.                                 STDIO3A.5     
!                                                                                  STDIO3A.6     
      INTEGER                                                                      STDIO3A.7     
     &     IU_STDIN                                                                STDIO3A.8     
!             UNIT NUMBER FOR STANDARD INPUT                                       STDIO3A.9     
     &   , IU_STDOUT                                                               STDIO3A.10    
!             UNIT NUMBER FOR STANDARD OUTPUT                                      STDIO3A.11    
     *   , IU_ERR                                                                  STDIO3A.12    
!             UNIT NUMBER FOR ERROR MESSAGES                                       STDIO3A.13    
!                                                                                  STDIO3A.14    
      PARAMETER(                                                                   STDIO3A.15    
     &     IU_STDIN=5                                                              STDIO3A.16    
     &   , IU_STDOUT=6                                                             STDIO3A.17    
     *   , IU_ERR=6                                                                STDIO3A.18    
     &   )                                                                         STDIO3A.19    
!                                                                                  STDIO3A.20    
!     ------------------------------------------------------------------           STDIO3A.21    
!     ------------------------------------------------------------------           TWOSTR3A.2     
!     COMDECK FOR TWO-STREAM RADIATION CODE.                                       TWOSTR3A.3     
!                                                                                  TWOSTR3A.4     
!     MODULE TO SET THE DEFINING NUMBERS FOR THE TWO-STREAM                        TWOSTR3A.5     
!     SCHEMES.                                                                     TWOSTR3A.6     
!                                                                                  TWOSTR3A.7     
      INTEGER                                                                      TWOSTR3A.8     
     &     IP_EDDINGTON                                                            TWOSTR3A.9     
!             EDDINGTON APPROXIMATION                                              TWOSTR3A.10    
     &   , IP_DISCRETE_ORD                                                         TWOSTR3A.11    
!             DISCRETE ORDINATE METHOD                                             TWOSTR3A.12    
     &   , IP_IFM                                                                  TWOSTR3A.13    
!             IMPROVED FLUX METHOD                                                 TWOSTR3A.14    
     &   , IP_PIFM85                                                               TWOSTR3A.15    
!             PRACTICAL IMPROVED FLUX METHOD                                       TWOSTR3A.16    
!             (VERSION OF ZDUNKOWSKI ET AL. 1985)                                  TWOSTR3A.17    
     &   , IP_ZDK_FLUX                                                             TWOSTR3A.18    
!             ZDUNKOWSKI'S FLUX METHOD                                             TWOSTR3A.19    
     &   , IP_KRSCHG_FLUX                                                          TWOSTR3A.20    
!             KERSCHGEN'S FLUX METHOD                                              TWOSTR3A.21    
     &   , IP_COAKLEY_CHYLEK_1                                                     TWOSTR3A.22    
!             COAKLEY & CHYLEK'S 1ST METHOD                                        TWOSTR3A.23    
     &   , IP_COAKLEY_CHYLEK_2                                                     TWOSTR3A.24    
!             COAKLEY & CHYLEK'S 2ND METHOD                                        TWOSTR3A.25    
     &   , IP_MEADOR_WEAVER                                                        TWOSTR3A.26    
!             MEADOR & WEAVER'S METHOD                                             TWOSTR3A.27    
     &   , IP_ELSASSER                                                             TWOSTR3A.28    
!             ELSASSER'S DIFFUSIVITY SCHEME                                        TWOSTR3A.29    
     &   , IP_2S_TEST                                                              TWOSTR3A.30    
!             USER'S DEFINED TEST APPROXIMATION.                                   TWOSTR3A.31    
     &   , IP_HEMI_MEAN                                                            TWOSTR3A.32    
!             HEMISPHERIC MEAN APPROXIMATION.                                      TWOSTR3A.33    
     &   , IP_PIFM80                                                               TWOSTR3A.34    
!             PRACTICAL IMPROVED FLUX METHOD                                       TWOSTR3A.35    
!             (VERSION OF ZDUNKOWSKI ET AL. 1980)                                  TWOSTR3A.36    
!                                                                                  TWOSTR3A.37    
      PARAMETER(                                                                   TWOSTR3A.38    
     &     IP_EDDINGTON=2                                                          TWOSTR3A.39    
     &   , IP_DISCRETE_ORD=4                                                       TWOSTR3A.40    
     &   , IP_IFM=5                                                                TWOSTR3A.41    
     &   , IP_PIFM85=6                                                             TWOSTR3A.42    
     &   , IP_ZDK_FLUX=7                                                           TWOSTR3A.43    
     &   , IP_KRSCHG_FLUX=8                                                        TWOSTR3A.44    
     &   , IP_COAKLEY_CHYLEK_1=9                                                   TWOSTR3A.45    
     &   , IP_COAKLEY_CHYLEK_2=10                                                  TWOSTR3A.46    
     &   , IP_MEADOR_WEAVER=11                                                     TWOSTR3A.47    
     &   , IP_ELSASSER=12                                                          TWOSTR3A.48    
     &   , IP_2S_TEST=14                                                           TWOSTR3A.49    
     &   , IP_HEMI_MEAN=15                                                         TWOSTR3A.50    
     &   , IP_PIFM80=16                                                            TWOSTR3A.51    
     &   )                                                                         TWOSTR3A.52    
!                                                                                  TWOSTR3A.53    
!     ------------------------------------------------------------------           TWOSTR3A.54    
!     ------------------------------------------------------------------           ELSASS3A.2     
!     COMDECK FOR TWO-STREAM RADIATION CODE.                                       ELSASS3A.3     
!                                                                                  ELSASS3A.4     
!     MODULE TO SET DIFFUSIVITY FOR ELSASSER'S SCHEME.                             ELSASS3A.5     
!                                                                                  ELSASS3A.6     
      REAL                                                                         ELSASS3A.7     
     &     ELSASSER_FACTOR                                                         ELSASS3A.8     
!             DIFFUSIVITY FACTOR FOR ELSASSER'S SCHEME                             ELSASS3A.9     
!                                                                                  ELSASS3A.10    
      PARAMETER(                                                                   ELSASS3A.11    
     &     ELSASSER_FACTOR=1.66E+00                                                ELSASS3A.12    
     &   )                                                                         ELSASS3A.13    
!                                                                                  ELSASS3A.14    
!     ------------------------------------------------------------------           ELSASS3A.15    
!     ------------------------------------------------------------------           ERROR3A.2     
!     COMDECK FOR TWO-STREAM RADIATION CODE.                                       ERROR3A.3     
!                                                                                  ERROR3A.4     
!     MODULE TO SET ERROR FLAGS IN THE RADIATION CODE.                             ERROR3A.5     
!                                                                                  ERROR3A.6     
      INTEGER                                                                      ERROR3A.7     
     &     I_NORMAL                                                                ERROR3A.8     
!             ERROR FREE CONDITION                                                 ERROR3A.9     
     &   , I_ERR_FATAL                                                             ERROR3A.10    
!             FATAL ERROR: IMMEDIATE RETURN                                        ERROR3A.11    
     &   , I_ABORT_CALCULATION                                                     ERROR3A.12    
!             CALCULATION ABORTED                                                  ERROR3A.13    
     &   , I_MISSING_DATA                                                          ERROR3A.14    
!             MISSING DATA ERROR: CONDITIONAL                                      ERROR3A.15    
     &   , I_ERR_IO                                                                ERROR3A.16    
!             I/O ERROR                                                            ERROR3A.17    
     &   , I_ERR_RANGE                                                             ERROR3A.18    
!             INTERPOLATION RANGE ERROR                                            ERROR3A.19    
     &   , I_ERR_EXIST                                                             ERROR3A.20    
!             EXISTENCE ERROR                                                      ERROR3A.21    
!                                                                                  ERROR3A.22    
      PARAMETER(                                                                   ERROR3A.23    
     &     I_NORMAL=0                                                              ERROR3A.24    
     &   , I_ERR_FATAL=1                                                           ERROR3A.25    
     &   , I_ABORT_CALCULATION=2                                                   ERROR3A.26    
     &   , I_MISSING_DATA=3                                                        ERROR3A.27    
     &   , I_ERR_IO=4                                                              ERROR3A.28    
     &   , I_ERR_RANGE=5                                                           ERROR3A.29    
     &   , I_ERR_EXIST=6                                                           ERROR3A.30    
     &   )                                                                         ERROR3A.31    
!                                                                                  ERROR3A.32    
!     ------------------------------------------------------------------           ERROR3A.33    
!                                                                                  RAD_ALL.24557 
!                                                                                  RAD_ALL.24558 
!                                                                                  RAD_ALL.24559 
!     DUMMY ARGUMENTS.                                                             RAD_ALL.24560 
      INTEGER   !, INTENT(OUT)                                                     RAD_ALL.24561 
     &     IERR                                                                    RAD_ALL.24562 
!             ERROR FLAG                                                           RAD_ALL.24563 
      INTEGER   !, INTENT(IN)                                                      RAD_ALL.24564 
     &     N_PROFILE                                                               RAD_ALL.24565 
!             NUMBER OF PROFILES                                                   RAD_ALL.24566 
     &   , I_LAYER_FIRST                                                           RAD_ALL.24567 
!             FIRST LAYER TO CONSIDER                                              RAD_ALL.24568 
     &   , I_LAYER_LAST                                                            RAD_ALL.24569 
!             LAST LAYER TO CONSIDER                                               RAD_ALL.24570 
     &   , I_2STREAM                                                               RAD_ALL.24571 
!             TWO STREAM SCHEME                                                    RAD_ALL.24572 
!                                                                                  RAD_ALL.24573 
!     OPTICAL PROPERTIES OF LAYER:                                                 RAD_ALL.24574 
      REAL      !, INTENT(IN)                                                      RAD_ALL.24575 
     &     ASYMMETRY(NPD_PROFILE, NPD_LAYER)                                       RAD_ALL.24576 
!             ASYMMETRY FACTOR                                                     RAD_ALL.24577 
     &   , OMEGA(NPD_PROFILE, NPD_LAYER)                                           RAD_ALL.24578 
!             ALBEDO OF SINGLE SCATTERING                                          RAD_ALL.24579 
!                                                                                  RAD_ALL.24580 
!                                                                                  RAD_ALL.24581 
!     COEFFICIENTS IN THE TWO-STREAM EQUATIONS:                                    RAD_ALL.24582 
      REAL      !, INTENT(OUT)                                                     RAD_ALL.24583 
     &     SUM(NPD_PROFILE, NPD_LAYER)                                             RAD_ALL.24584 
!             SUM OF ALPHA_1 AND ALPHA_2                                           RAD_ALL.24585 
     &   , DIFF(NPD_PROFILE, NPD_LAYER)                                            RAD_ALL.24586 
!             DIFFERENCE OF ALPHA_1 AND ALPHA_2                                    RAD_ALL.24587 
!                                                                                  RAD_ALL.24588 
!     LOCAL VARIABLES.                                                             RAD_ALL.24589 
      INTEGER                                                                      RAD_ALL.24590 
     &     I                                                                       RAD_ALL.24591 
!             LOOP VARIABLE                                                        RAD_ALL.24592 
     &   , L                                                                       RAD_ALL.24593 
!             LOOP VARIABLE                                                        RAD_ALL.24594 
!                                                                                  RAD_ALL.24595 
      REAL                                                                         RAD_ALL.24596 
     &     ROOT_3                                                                  RAD_ALL.24597 
!             SQUARE ROOT OF 3                                                     RAD_ALL.24598 
!                                                                                  RAD_ALL.24599 
!                                                                                  RAD_ALL.24600 
      PARAMETER(                                                                   RAD_ALL.24601 
     &     ROOT_3=1.7320508075688772E+00                                           RAD_ALL.24602 
     &   )                                                                         RAD_ALL.24603 
!                                                                                  RAD_ALL.24604 
!                                                                                  RAD_ALL.24605 
!                                                                                  RAD_ALL.24606 
!                                                                                  RAD_ALL.24607 
      IF (I_2STREAM.EQ.IP_EDDINGTON) THEN                                          RAD_ALL.24608 
         DO I=I_LAYER_FIRST, I_LAYER_LAST                                          RAD_ALL.24609 
            DO L=1, N_PROFILE                                                      RAD_ALL.24610 
               SUM(L, I)=1.5E+00*(1.0E+00                                          RAD_ALL.24611 
     &            -OMEGA(L, I)*ASYMMETRY(L, I))                                    RAD_ALL.24612 
               DIFF(L, I)=2.0E+00*(1.0E+00-OMEGA(L, I))                            RAD_ALL.24613 
            ENDDO                                                                  RAD_ALL.24614 
         ENDDO                                                                     RAD_ALL.24615 
!                                                                                  RAD_ALL.24616 
      ELSE IF (I_2STREAM.EQ.IP_ELSASSER) THEN                                      RAD_ALL.24617 
         DO I=I_LAYER_FIRST, I_LAYER_LAST                                          RAD_ALL.24618 
            DO L=1, N_PROFILE                                                      RAD_ALL.24619 
               SUM(L, I)=ELSASSER_FACTOR                                           RAD_ALL.24620 
     &            -1.5E+00*OMEGA(L, I)*ASYMMETRY(L, I)                             RAD_ALL.24621 
               DIFF(L, I)=ELSASSER_FACTOR*(1.0E+00-OMEGA(L, I))                    RAD_ALL.24622 
            ENDDO                                                                  RAD_ALL.24623 
         ENDDO                                                                     RAD_ALL.24624 
!                                                                                  RAD_ALL.24625 
      ELSE IF (I_2STREAM.EQ.IP_DISCRETE_ORD) THEN                                  RAD_ALL.24626 
         DO I=I_LAYER_FIRST, I_LAYER_LAST                                          RAD_ALL.24627 
            DO L=1, N_PROFILE                                                      RAD_ALL.24628 
               SUM(L, I)=ROOT_3*(1.0E+00                                           RAD_ALL.24629 
     &            -OMEGA(L, I)*ASYMMETRY(L, I))                                    RAD_ALL.24630 
               DIFF(L, I)=ROOT_3*(1.0E+00-OMEGA(L, I))                             RAD_ALL.24631 
            ENDDO                                                                  RAD_ALL.24632 
         ENDDO                                                                     RAD_ALL.24633 
!                                                                                  RAD_ALL.24634 
      ELSE IF (I_2STREAM.EQ.IP_PIFM85) THEN                                        RAD_ALL.24635 
         DO I=I_LAYER_FIRST, I_LAYER_LAST                                          RAD_ALL.24636 
            DO L=1, N_PROFILE                                                      RAD_ALL.24637 
               SUM(L, I)=2.0E+00                                                   RAD_ALL.24638 
     &            -1.5E+00*OMEGA(L, I)*ASYMMETRY(L, I)                             RAD_ALL.24639 
               DIFF(L, I)=2.0E+00*(1.0E+00-OMEGA(L, I))                            RAD_ALL.24640 
            ENDDO                                                                  RAD_ALL.24641 
         ENDDO                                                                     RAD_ALL.24642 
!                                                                                  RAD_ALL.24643 
      ELSE IF (I_2STREAM.EQ.IP_2S_TEST) THEN                                       RAD_ALL.24644 
         DO I=I_LAYER_FIRST, I_LAYER_LAST                                          RAD_ALL.24645 
            DO L=1, N_PROFILE                                                      RAD_ALL.24646 
               SUM(L, I)=1.5E+00                                                   RAD_ALL.24647 
     &            -1.5E+00*OMEGA(L, I)*ASYMMETRY(L, I)                             RAD_ALL.24648 
               DIFF(L, I)=1.5E+00*(1.0E+00-OMEGA(L, I))                            RAD_ALL.24649 
            ENDDO                                                                  RAD_ALL.24650 
         ENDDO                                                                     RAD_ALL.24651 
!                                                                                  RAD_ALL.24652 
      ELSE IF (I_2STREAM.EQ.IP_HEMI_MEAN) THEN                                     RAD_ALL.24653 
         DO I=I_LAYER_FIRST, I_LAYER_LAST                                          RAD_ALL.24654 
            DO L=1, N_PROFILE                                                      RAD_ALL.24655 
               SUM(L, I)=2.0E+00                                                   RAD_ALL.24656 
     &            *(1.0E+00-OMEGA(L, I)*ASYMMETRY(L, I))                           RAD_ALL.24657 
               DIFF(L, I)=2.0E+00*(1.0E+00-OMEGA(L, I))                            RAD_ALL.24658 
            ENDDO                                                                  RAD_ALL.24659 
         ENDDO                                                                     RAD_ALL.24660 
!                                                                                  RAD_ALL.24661 
      ELSE IF (I_2STREAM.EQ.IP_PIFM80) THEN                                        RAD_ALL.24662 
         DO I=I_LAYER_FIRST, I_LAYER_LAST                                          RAD_ALL.24663 
            DO L=1, N_PROFILE                                                      RAD_ALL.24664 
               SUM(L, I)=2.0E+00                                                   RAD_ALL.24665 
     &            -1.5E+00*OMEGA(L, I)*ASYMMETRY(L, I)                             RAD_ALL.24666 
     &            -0.5E+00*OMEGA(L, I)                                             RAD_ALL.24667 
               DIFF(L, I)=2.0E+00*(1.0E+00-OMEGA(L, I))                            RAD_ALL.24668 
            ENDDO                                                                  RAD_ALL.24669 
         ENDDO                                                                     RAD_ALL.24670 
!                                                                                  RAD_ALL.24671 
      ELSE IF (I_2STREAM.EQ.IP_IFM) THEN                                           RAD_ALL.24672 
         WRITE(IU_ERR, '(/A)')                                                     RAD_ALL.24673 
     &      '*** ERROR: THE IMPROVED FLUX METHOD HAS '                             RAD_ALL.24674 
     &      //'NOT BEEN IMPLEMENTED.'                                              RAD_ALL.24675 
         IERR=I_ERR_FATAL                                                          RAD_ALL.24676 
         RETURN                                                                    RAD_ALL.24677 
!                                                                                  RAD_ALL.24678 
      ELSE IF (I_2STREAM.EQ.IP_ZDK_FLUX) THEN                                      RAD_ALL.24679 
         WRITE(IU_ERR, '(/A)')                                                     RAD_ALL.24680 
     &      '*** ERROR: ZDUNKOWSKI''S FLUX METHOD HAS '                            RAD_ALL.24681 
     &      //'NOT BEEN IMPLEMENTED.'                                              RAD_ALL.24682 
         IERR=I_ERR_FATAL                                                          RAD_ALL.24683 
         RETURN                                                                    RAD_ALL.24684 
!                                                                                  RAD_ALL.24685 
      ELSE IF (I_2STREAM.EQ.IP_KRSCHG_FLUX) THEN                                   RAD_ALL.24686 
         WRITE(IU_ERR, '(/A)')                                                     RAD_ALL.24687 
     &      '*** ERROR: KERSCHGEN''S FLUX METHOD HAS '                             RAD_ALL.24688 
     &      //'NOT BEEN IMPLEMENTED.'                                              RAD_ALL.24689 
         IERR=I_ERR_FATAL                                                          RAD_ALL.24690 
         RETURN                                                                    RAD_ALL.24691 
!                                                                                  RAD_ALL.24692 
      ELSE IF (I_2STREAM.EQ.IP_COAKLEY_CHYLEK_1) THEN                              RAD_ALL.24693 
         WRITE(IU_ERR, '(/A)')                                                     RAD_ALL.24694 
     &      '*** ERROR: COAKLEY-CHYLEK''S FIRST METHOD HAS '                       RAD_ALL.24695 
     &      //'NOT BEEN IMPLEMENTED.'                                              RAD_ALL.24696 
         IERR=I_ERR_FATAL                                                          RAD_ALL.24697 
         RETURN                                                                    RAD_ALL.24698 
!                                                                                  RAD_ALL.24699 
      ELSE IF (I_2STREAM.EQ.IP_COAKLEY_CHYLEK_2) THEN                              RAD_ALL.24700 
         WRITE(IU_ERR, '(/A)')                                                     RAD_ALL.24701 
     &      '*** ERROR: COAKLEY-CHYLEK''S SECOND METHOD HAS '                      RAD_ALL.24702 
     &      //'NOT BEEN IMPLEMENTED.'                                              RAD_ALL.24703 
         IERR=I_ERR_FATAL                                                          RAD_ALL.24704 
         RETURN                                                                    RAD_ALL.24705 
!                                                                                  RAD_ALL.24706 
      ELSE IF (I_2STREAM.EQ.IP_MEADOR_WEAVER) THEN                                 RAD_ALL.24707 
         WRITE(IU_ERR, '(/A)')                                                     RAD_ALL.24708 
     &      '*** ERROR: MEADOR & WEAVER''S METHOD HAS '                            RAD_ALL.24709 
     &      //'NOT BEEN IMPLEMENTED.'                                              RAD_ALL.24710 
         IERR=I_ERR_FATAL                                                          RAD_ALL.24711 
         RETURN                                                                    RAD_ALL.24712 
!                                                                                  RAD_ALL.24713 
      ELSE                                                                         RAD_ALL.24714 
         WRITE(IU_ERR, '(/A)')                                                     RAD_ALL.24715 
     &      '*** ERROR: AN ILLEGAL PARAMETER HAS BEEN SUPPLIED '                   RAD_ALL.24716 
     &      //'TO DEFINE THE 2-STREAM SCHEME.'                                     RAD_ALL.24717 
         IERR=I_ERR_FATAL                                                          RAD_ALL.24718 
         RETURN                                                                    RAD_ALL.24719 
!                                                                                  RAD_ALL.24720 
      ENDIF                                                                        RAD_ALL.24721 
!                                                                                  RAD_ALL.24722 
!                                                                                  RAD_ALL.24723 
!                                                                                  RAD_ALL.24724 
      RETURN                                                                       RAD_ALL.24725 
      END 
