!+ Subroutine to write a formatted list of transmissions.
!
! Method:
!	Straightforward.
!
! Current Owner of Code: J. M. Edwards
!
! History:
!	Version		Date			Comment
!	1.0		12-04-95		First Version under RCS
!						(J. M. Edwards)
!
! Description of Code:
!   FORTRAN 77  with extensions listed in documentation.
!
!- ---------------------------------------------------------------------
      SUBROUTINE WRITE_TRANS_FORM(TYPE_ABSORB_SET
     &   , TRANS_TYPE
     &   , LENGTH_SET, BAND_SET, INDEX_SET, P_SET, T_SET
     &   , U_SET, TRANS_SET
     &   , WAVE_LENGTH_SHORT_SET, WAVE_LENGTH_LONG_SET
     &   )
!
!
      IMPLICIT NONE
!
!
!     INCLUDE HEADER FILES.
      INCLUDE 'incl/dimensions_pp.ucf'
      INCLUDE 'incl/def_pp_io.icf'
      INCLUDE 'incl/gas_list.pcf'
      INCLUDE 'incl/gas_list.ncf'
      INCLUDE 'incl/file_type.pcf'
!
!     DUMMY ARGUMENTS.
      CHARACTER	!, INTENT(IN)
     &     TRANS_TYPE*4
!             TYPE OF TRANSMITTANCE
      INTEGER	!, INTENT(IN)
     &     TYPE_ABSORB_SET
!             ABSORBER TYPES
     &   , BAND_SET
!             ARRAY OF BANDS
     &   , LENGTH_SET
!             LENGTHS OF THE SETS
     &   , INDEX_SET
!             INDEX OF SET
      REAL*8	!, INTENT(IN)
     &     P_SET
!             PRESSURES
     &   , T_SET
!             TEMPERATURES
     &   , U_SET(NPD_AMOUNT)
!             AMOUNTS OF GASES
     &   , TRANS_SET(NPD_AMOUNT)
!             TRANSMITTANCES
     &   , WAVE_LENGTH_SHORT_SET
!             SHORTER WAVELENGTHS
     &   , WAVE_LENGTH_LONG_SET
!             LONGER WAVELENGTHS
!
!     LOCAL VARIABLES
      INTEGER
     &     J
!             LOOP VARIABLE
!
!     SET NAMES OF GASES.
      INCLUDE 'incl/gas_names.dcf'
!
!
      WRITE(IU_TRANSMISSION_FORM, '(A13, I5, //)') '*FILE TYPE = '
     &   , IT_FILE_LINE_TRANS_FORM
      WRITE(IU_TRANSMISSION_FORM, '(A4, 1X, A/)')
     &   TRANS_TYPE, 'TRANSMITTANCE AGAINST AMOUNT OF ABSORBER:'
      WRITE(IU_TRANSMISSION_FORM, '(A4, 1X, A20, 2X, A7, I5)') 'GAS:'
     &   , NAME_ABSORB(TYPE_ABSORB_SET)
     &   , 'INDEX: ',INDEX_SET
      WRITE(IU_TRANSMISSION_FORM
     &   , '(A13, 1X, 1PE10.3, 1X, A2, 2X, A17, 1X, 1PE10.3, 1X, A2)')
     &   'AT PRESSURE =', P_SET, 'Pa', 'AND TEMPERATURE =', T_SET, 'K.'
      WRITE(IU_TRANSMISSION_FORM
     &   , '(A8, I5, A1, 3X, 1PE10.3, A4, 2X, 1PE10.3, A2, /)')
     &   'IN BAND ', BAND_SET, ':'
     &   , WAVE_LENGTH_SHORT_SET, 'm TO'
     &   , WAVE_LENGTH_LONG_SET, 'm.'
      WRITE(IU_TRANSMISSION_FORM, '(6X, A18, 5X, A14)')
     &   'AMOUNT OF ABSORBER', 'TRANSMITTANCE'
      WRITE(IU_TRANSMISSION_FORM, '(13X, A5)')
     &   'kg/m2'
      DO J=1, LENGTH_SET
         WRITE(IU_TRANSMISSION_FORM, '(2(7X, 1PE15.8))')
     &      U_SET(J), TRANS_SET(J)
      ENDDO
      WRITE(IU_TRANSMISSION_FORM, '(6X)')
!
!
      RETURN
      END
