!+ Function to calculate the Rayleigh scattering coefficient at S.T.P.
!
! Method:
!	Straightforward.
!
! Current Owner of Code: J. M. Edwards
!
! History:
!	 Version 	   Date	  		Comment
!   
!	 1.0		   12-04-95		First Version under RCS
!						(J. M. Edwards)
!
! Description of Code:
!   FORTRAN 77 with extensions listed in documentation. 
!
!- ---------------------------------------------------------------------
      FUNCTION RAYLEIGH_SCATTER(LAMBDA)
!
!
      IMPLICIT NONE
!
!
!     INCLUDE HEADER FILES.
      INCLUDE 'incl/physical_constants_pp.ccf'
      INCLUDE 'incl/physical_constants_0.ccf'
      INCLUDE 'incl/math_cnst.ccf'
!
!     DUMMY VARIABLES.
      REAL*8 	!, INTENT(OUT)
     &     RAYLEIGH_SCATTER
!             NAME OF FUNCTION
      REAL*8 	!, INTENT(IN)
     &     LAMBDA
!             WAVELENGTH
!
!     LOCAL VARIABLES.
      REAL*8
     &     REFRACT_INDEX_M1
!             REFRACTIVE INDEX AT 0C LESS 1.
     &   , LAMBDA_M2
!             RECIPROCAL OF WAVELENGTH
!             SQUARED
!
!
!     CALCULATE THE REFRACTIVE INDEX USING EDLEN'S FORMULA CONVERTED TO
!     APPLY AT 273.16K.
      LAMBDA_M2=1.0D+00/(LAMBDA*LAMBDA)
      REFRACT_INDEX_M1=6.09794D-05+2.79626D+10/(1.46D+14-LAMBDA_M2)
     &   +2.42105D+08/(4.1D+13-LAMBDA_M2)
!
!     USE THE STANDARD EXPRESSION FOR THE RAYLEIGH SCATTERING
!     COEFFICIENT, BUT INCLUDE AN EXTRA DENSITY FACTOR TO GIVE IT
!     IN MASS UNITS.
      RAYLEIGH_SCATTER
     &   =(8.0D+00*PI**3/3.0D+00)*(((REFRACT_INDEX_M1+2.0D+00)
     &   *REFRACT_INDEX_M1*LAMBDA_M2)**2
     &   /N_AVOGADRO)*((6.0D+00+3.0D+00*RHO_N)/(6.0D+00-7.0D+00*RHO_N))
     &   *(MOL_WEIGHT_AIR/RHO_AIR_STP**2)
!
!
      RETURN
      END
