!+ Subroutine to calculate the saturated mixing ratio for ice.
!
! Method:
!	The standard Goff-Gratsch formula is implemented.
!
! Current Owner of Code: J. M. Edwards
!
! History:
!	Version		Date			Comment
!	1.0		12-04-95		First Version under RCS
!						(J. M. Edwards)
!
! Description of Code:
!   FORTRAN 77  with extensions listed in documentation.
!
!- ---------------------------------------------------------------------
      SUBROUTINE QSAT_GG_ICE(QS, T, P)
!
!
      IMPLICIT NONE
!
!
!     DUMMY ARGUMENTS
      REAL*8	!, INTENT(IN)
     &     T
!             TEMPERATURE
     &   , P
!             PRESSURE
      REAL*8	!, INTENT(OUT)
     &     QS
!             SATURATION MIXING RATIO
!
!     LOCAL VARIABLES.
      REAL*8
     &     X
     &   , U1
     &   , U2
     &   , U3
!             TEMPORARY VARIABLES
     &   , EW
!             SATURATION VAPOUR PRESSURE OF WATER VAPOUR
     &   , R
!             HUMIDITY MIXING RATIO
!
!
!
      X=2.7316D+02/T
      U1=-9.09718D+00*(X-1.0D+00)
      U2=-3.56654D+00*LOG10(X)
      U3=8.76793D+00*(1.0D+00-1.0D+00/X)
      EW=6.1071D+02*1.0D+01**(U1+U2+U3)
      R=6.2197D-01*EW/(P-EW)
      QS=R/(1.0D+00+R)
!
!
!
      RETURN
      END
